function cal_cds_psf_coeff_wave,lambda,X_PSF=X_PSF,Y_PSF=Y_PSF
;+
;NAME: 
;		CAL_CDS_PSF_COEFF_WAVE
; Project:
;	    SOHO - CDS
;
;CREATED BY:	David Christophe, IAS, march 1, 1999
;
;CALLING SEQUENCE:
;	C_L=cal_cds_psf_coeff_wave(lambda)
;
;PURPOSE: 
;	 get the Point Spread Function in function of the
;	 wavelength.

;
;INPUTS:
;	lambda	: reference wavelength
;
;OUPUTS:
;	C_L : The coefficients of the polynomial funtion describing the
;	      PSF (CDS telescope)in log-log scale.
;
;	X_PSF : abscisse of PSF courbe for lambda (in arcsec)
;	
;	Y_PSF : value of PSF for lambda calculated with C_L polynomial
;		coefficient.
;
; MODIFICATION HISTORY:
;	David Christophe, IAS, jun 28, 1999
;
;*********************************************************************
;*********************************************************************
;-
C_L=fltarr(6)
C_ref=[0.988441,-9.38801,6.13821,-2.73354,0.573765,-0.0449529]
;C_ref=[-2.25017,-2.63259,0,0,0,0]
alpha=lambda/703.
X_alpha=alog10(alpha)
;
C_L(5)=C_ref(5)
C_L(4)=(-5*X_alpha)*C_ref(5)+C_ref(4)
C_L(3)=10*X_alpha^2*C_ref(5)-4*X_alpha*C_ref(4)+C_ref(3)
C_L(2)=-10*X_alpha^3*C_ref(5)+6*X_alpha^2*C_ref(4)-3*X_alpha*C_ref(3)+C_ref(2)
C_L(1)=5*X_alpha^4*C_ref(5)-4*X_alpha^3*C_ref(4)+3*X_alpha^2*C_ref(3)-2*X_alpha*C_ref(2)+C_ref(1)
C_L(0)=-X_alpha^5*C_ref(5)+X_alpha^4*C_ref(4)-X_alpha^3*C_ref(3)+X_alpha^2*C_ref(2)-X_alpha*C_ref(1)+C_ref(0)-4*X_alpha
;
X_LOGPSF=((findgen(10000)*(3.7-1)/9999.)+1)
Y_PSF=10^poly(X_logPSF,C_L)
X_PSF=10^X_logPSF
return,C_L

end